resource "oci_core_volume_backup_policy" "sei_backup_policy" {
    count = var.enable_boot_volume_backup == "true" ? 1 : 0
    compartment_id = var.ocid_compartment_app
    display_name = "sei-backup-policy-${var.environment}"
    schedules {
      backup_type       = "FULL"
      day_of_month      = -1
      day_of_week       = "SUNDAY"
      hour_of_day       = 0
      offset_seconds    = 0
      offset_type       = "STRUCTURED"
      period            = "ONE_WEEK"
      retention_seconds = 604800
      time_zone         = "REGIONAL_DATA_CENTER_TIME"
    }
    schedules {
      backup_type       = "FULL"
      day_of_month      = 1
      hour_of_day       = 0
      offset_seconds    = 0
      offset_type       = "STRUCTURED"
      period            = "ONE_MONTH"
      retention_seconds = 16070400
      time_zone         = "REGIONAL_DATA_CENTER_TIME"
    }
    schedules {
      backup_type       = "INCREMENTAL"
      day_of_month      = -1
      hour_of_day       = 0
      offset_seconds    = 0
      offset_type       = "STRUCTURED"
      period            = "ONE_DAY"
      retention_seconds = 604800
      time_zone         = "REGIONAL_DATA_CENTER_TIME"
    }
}

data "oci_core_boot_volumes" "all_boot_volumes" {
  count = var.enable_boot_volume_backup == "true" ? 1 : 0
  compartment_id      = var.ocid_compartment_app
  availability_domain = data.oci_identity_availability_domain.ad.name
}

resource "oci_core_volume_backup_policy_assignment" "sei_volume_group_backup_assignment" {
  count = var.enable_boot_volume_backup == "true" ? 1 : 0
  asset_id          = oci_core_volume_group.sei_servers_volume_group[count.index].id
  policy_id         = oci_core_volume_backup_policy.sei_backup_policy[count.index].id
}

resource "oci_core_volume_group" "sei_servers_volume_group" {
  count = var.enable_boot_volume_backup == "true" ? 1 : 0
  availability_domain = data.oci_identity_availability_domain.ad.name
  compartment_id      = var.ocid_compartment_app

  source_details {
    type = "volumeIds"
    volume_ids = concat(
      oci_core_instance.sei-instance[*].boot_volume_id,
      oci_core_instance.solr-instance[*].boot_volume_id,
      oci_core_instance.memcached-instance[*].boot_volume_id,
      oci_core_instance.sip-instance[*].boot_volume_id,
      oci_core_instance.jod-instance[*].boot_volume_id
    )
  }

  display_name = "sei-volume-group-${var.environment}"
}